Exécution de Linux virtuel à l'aide de qemu sous Windows

Voici comment j'exécute une version minimale de CentOS 7 sur un Windows 7 Enterprise, 64 bits, sans être membre du groupe administrateur (non-admin).

L'idée de base est :

Téléchargez qemu pour Windows et décompressez-le n'importe où
Téléchargez une image ISO de la distribution Linux que vous souhaitez exécuter
Créez un fichier qui sera le disque dur de votre machine virtuelle
Lancez qemu, en démarrant à partir de l'image du CD
Installer le système d'exploitation
Redémarrez la machine virtuelle, cette fois sans l'image du CD

La mise en réseau et les graphismes sophistiqués sont difficiles à obtenir. Toujours en difficulté, en fait...

1. Télécharger QEMU

Utilisez un binaire précompilé trouvé sur la page des liens QEMU. J'ai utilisé la version 2.8.0 pour cela.

Pour "installer" cette version en tant que non-administrateur, ouvrez une invite de commande, lancez la commande set __COMPAT_LAYER=RunAsInvoker et exécutez qemu-w64-setup-20170131.exe à partir de cette invite. Installez-le dans un dossier où vous disposez d'autorisations d'écriture, comme "Mes documents" ou autre.

2. Télécharger une image ISO de Linux

Encore une fois, aidez-vous. J'ai utilisé la distribution Minimal de CentOS 7, le fichier s'appelle CentOS-7-x86_64-Minimal-1611.iso .

3. Créer un disque dur virtuel

J'ai utilisé un fichier batch pour cela. Copiez ce qui suit dans un fichier nommé createvm.bat et ajustez les variables en fonction de votre environnement :

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4. Exécutez QEMU, en démarrant à partir du CD virtuel

Utilisez un lot pour celui-ci, car vous pourriez l'utiliser souvent. Copiez ce qui suit dans installvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot

5. Installer le système d'exploitation

J'ai eu des problèmes avec le programme d'installation de l'interface graphique. Lorsque vous êtes invité à installer CentOS, appuyez sur TAB clé et remplacer le mot quiet à la fin de cette ligne avec le mot text .

Suivez les instructions d'installation à l'écran. Une fois l'installation terminée, la machine virtuelle se fermera. Cela peut prendre un certain temps, surtout en tant qu'utilisateur non administrateur.

6. Exécutez votre image Linux dans QEMU

Cette étape est ce que vous ferez encore et encore pour exécuter la machine virtuelle chaque fois que vous en aurez besoin. Copiez ce qui suit dans runvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

J'ai ajouté un portforward local :si vous utilisez ssh/putty sur localhost:2222, vous accéderez au démon SSH de votre VM. Attention, firewalld ou iptables pourrait bloquer le trafic, selon la façon dont vous avez installé Linux.

Le manuel Qemu serait un bon point de départ. Cela vous aidera à déterminer ce que vous êtes censé faire ensuite, c'est-à-dire dire à qemu quoi faire et exactement comment le faire.