Remplacer les lignes correspondant à un motif par des lignes d'un autre fichier dans l'ordre ?

Je souhaite remplacer les lignes correspondant à un motif d'un fichier à partir des lignes dans l'ordre d'un autre fichier, par exemple, étant donné :

fichier1.txt :

aaaaaa
bbbbbb
!! 1234
!! 4567
ccccc
ddddd
!! 1111

nous aimons remplacer les lignes commençant par !! avec les lignes de ce fichier :

fichier2.txt :

first line
second line
third line

donc le résultat devrait être :

aaaaaa
bbbbbb
first line
second line
ccccc
ddddd
third line

Réponse acceptée :

Facile peut être fait avec awk

awk '
    /^!!/{                    #for line stared with `!!`
        getline <"file2.txt"  #read 1 line from outer file into $0 
    }
    1                         #alias for `print $0`
    ' file1.txt

Autre version

awk '
    NR == FNR{         #for lines in first file
        S[NR] = $0     #put line in array `S` with row number as index 
        next           #starts script from the beginning
    }
    /^!!/{             #for line stared with `!!`
        $0=S[++count]  #replace line by corresponded array element
    }
    1                  #alias for `print $0`
    ' file2.txt file1.txt